Basic 8051 tutorial 2 2014-04-15

    org    0        ; Reset vector
    sjmp    Start

    org    30H        ; Code starts here
Start:
    clr    A        ; A = 0
While:
    acall    keypad    ; Fetch keypress ( mono...only one key at a time )
    acall    delay    ; delay so we see it
    acall    Display    ; Show on display
    sjmp    While    ; do it again ( Forever loop )

keypad:
    mov    R1,#0EFH    ; keymask
    mov    R2,#3        ; Three columns
    mov    A,#1
OLoop:
    clr    C
    mov    P0,R1        ; ready keypad mask
    jb    P0.0,row2    ; Key pressed? row 1
    sjmp    keydone    ; found a key
row2:
    jb    P0.1,row3    ; Key pressed? row 2
    add    A,#1
    sjmp    keydone    ; found a key
row3:
    jb    P0.2,row4    ; Key pressed? row 3
    add    A,#2
    sjmp    keydone    ; found a key
row4:
    jb    P0.3,nextcol    ; Key pressed? row 4
    add    A,#3
    sjmp    keydone    ; found a key
nextcol:
    add    A,#4        ; add row count...0,4,8 + key press
    push    Acc        ; save count
    mov    A,R1        ; get mask
    setb    C        ; Rotate with
    rlc    A            ; carry R1 mask
    mov    R1,A        ; store new mask
    pop    Acc            ; restore the count
    djnz    R2,OLoop    ; Last column???
    clr    A            ; No keys detected...
keydone:            ; return with keypad condition
    ret


Display:
    mov    DPTR,#digits    ; Use A to get 7 segment pattern
    movc    A,@A+DPTR    ;
    ;cpl    A        ; Common cathode... Uncomment for common anode.
    mov    P1,A        ;  put pattern on port 1
    ret

delay:    mov    R2,#225    ; 2 clock cycles (call)        = 2
    mov    R1,#0        ; 2 clock cycles (loading)    = 2
d1:    
   djnz    R1,d1    ; 2 * 256 clock cycles *225    = 115200
    djnz    R2,d1    ; 2 * 225 clock cycles     = 450
    ret                ; 2 clock cycles (return)    = 2

digits:    db    03FH,006H,005BH,04FH,066H,06DH,07DH,007H,07FH,06FH,077H,07CH,039H            ; 7 segment patterns 0 to C
    end

#include<8051.h>        // definition file.

unsigned char digits[] = {0x3F,0x06,0x5B,0x4F,0x66,0x6D,0x7D
                ,0x07,0x7F,0x6F,0x77,0x7C,0x39};

void delay(void)        // How to get 125mS..
    {
    int x = 10500;        // The while statement consumes 11.89uS (11 clock cycles )
    while(x--);        // So 10500 * 11.89uS = nearly 125mS.
    }           

char keypad(void)
    {
    unsigned char keymask = 0xEF;
    char key = 0, x;
    for(x=0;x<3;x++)        // Three columns.
        {
        P0 = keymask;    // check each
        if(!P0_0) key = 1;    // bit for
        if(!P0_1) key = 2;
        if(!P0_2) key = 3;    // key detect.
        if(!P0_3) key = 4;
        if(key)
            {        // If we see a key press we
            key += (x*4);    // need to add in the loop.
            return key;
            }
        keymask<<=1;    // We have no status control in C so we manually
        keymask++;        // shift a bit into the mask register..
        }            // or the LSBit will be an output !sizzle!..
    return key;
    }
   
void display(unsigned char dt)
    {
    P1 = ~digits[dt];    // Common anode uses '~' delete for common cathode.   
    }

void main(void)            // Main entry point
    {
   
    while(1)            // Forever loop
        {
        display(keypad());    // we can nest functions in C like this
        delay();        // delay..
        }
    }